'************************************************

'ADF4117 PLL Ver1.1.1

'2007.01.04

'JA4LAO_Tuneo.Ito

'AT90S2313-10PC

'POS-535 260MHz-550Mhz

'************************************************



Config Portd.3 = Output                                     'PLL OUT

Config Portd.4 = Output                                     'PLL OUT

Config Portd.5 = Output                                     'PLL OUT

Config Portd.1 = Input                                      'SPAN SW

Config Portd.0 = Input                                      'RE

Config Portd.2 = Input                                      'RE

Config Debounce = 3



Dim I As Byte

Dim Freq As Long                                            'FREQUENCY DATA

Dim Freq1 As Long

Dim Init1 As Long                                           'INITIALIZATION LATCH

Dim Ref As Long                                             'REFERENCE COUNTER LATCH

Dim Cndata As Long

Dim Freqb1 As String * 32

Dim A As String * 1

Dim S As Byte

Dim Kankaku As Word

Dim Freq_hyouji_1 As Word



Freq = 30000                                                '初期周波数 300MHz

Init1 = 71                                                  '01000111

'Init2 = 70                                                  '01000110

'Init3 = 66                                                  '01000010

Ref = 5200                                                  '10100010100

S = 1

Kankaku = 1                                                 '初期設定　１０ＫＨｚ



Cursor Off : Cls

Gosub Hyouji

Locate 2 , 9 : Lcd " 10Khz"

Gosub Dataout1



Do

       Debounce Pind.0 , 0 , Updown , Sub

       Debounce Pind.1 , 0 , Kankakusetei , Sub

Loop



End



Updown:

Waitus 1

If Pind.2 = 0 Then

       Freq = Freq - Kankaku

Else

       Freq = Freq + Kankaku

End If

Gosub Hyouji

Gosub Dataout2

Return





Settei1:

Freqb1 = Bin(cndata)

Freqb1 = Right(freqb1 , 21)

Freq1 = Binval(freqb1)

Rotate Freq1 , Left , 2

Incr Freq1

Freqb1 = Bin(freq1)

Freqb1 = Right(freqb1 , 21)

Return



Settei2:

Freqb1 = Bin(cndata)

Freqb1 = Right(freqb1 , 21)

Return



Dataout:

Set Portd.3

Waitus 10

Reset Portd.3

Waitus 10

For I = 1 To 21

     A = Mid(freqb1 , I , 1)

     Select Case A

               Case "1"

                      Set Portd.4 : Waitus 10

               Case "0"

                      Reset Portd.4 : Waitus 10

     End Select

     Set Portd.5 : Waitus 10

     Reset Portd.4

     Reset Portd.5

     Waitus 10

Next I

Set Portd.3 : Waitus 10 : Reset Portd.3 : Waitus 10

Return



Dataout1:

Cndata = Init1 : Gosub Settei2 : Gosub Dataout

Cndata = Init1 -1 : Gosub Settei2 : Gosub Dataout

Cndata = Ref : Gosub Settei2 : Gosub Dataout

Dataout2:

Cndata = Freq : Gosub Settei1 : Gosub Dataout

Cndata = Init1 -5 : Gosub Settei2 : Gosub Dataout

Return



Kankakusetei:

Waitms 200

Incr S

If S > 5 Then S = 1

Select Case S

          Case 1

                 Kankaku = 1

                 Locate 2 , 9 : Lcd " 10Khz"

          Case 2

                 Kankaku = 10

                 Locate 2 , 9 : Lcd "100Khz"

          Case 3

                 Kankaku = 100

                 Locate 2 , 9 : Lcd "  1Mhz"

          Case 4

                 Kankaku = 1000

                 Locate 2 , 9 : Lcd " 10Mhz"

          Case 5

                 Kankaku = 10000

                 Locate 2 , 9 : Lcd "100Mhz"

End Select

Return



Hyouji:

Locate 1 , 3 : Lcd "F= " : Lcd Freq : Lcd "0KHz"

Return